lib/indirect.pm

   1 package indirect;
   2
   3 use 5.008001;
   4
   5 use strict;
   6 use warnings;
   7
   8 =head1 NAME
   9
  10 indirect - Lexically warn about using the indirect object syntax.
  11
  12 =head1 VERSION
  13
  14 Version 0.20
  15
  16 =cut
  17
  18 our $VERSION;
  19 BEGIN {
  20  $VERSION = '0.20';
  21 }
  22
  23 =head1 SYNOPSIS
  24
  25     # In a script
  26     no indirect;
  27     my $x = new Apple 1, 2, 3; # warns
  28     {
  29      use indirect;
  30      my $y = new Pear; # ok
  31      {
  32       no indirect hook => sub { die "You really wanted $_[0]\->$_[1] at $_[2]:$_[3]" };
  33       my $z = new Pineapple 'fresh'; # croaks 'You really wanted Pineapple->new at blurp.pm:13'
  34      }
  35     }
  36     try { ... }; # warns
  37
  38     no indirect ':fatal';
  39     if (defied $foo) { ... } # croaks, note the typo
  40
  41     # From the command-line
  42     perl -M-indirect -e 'my $x = new Banana;' # warns
  43
  44     # Or each time perl is ran
  45     export PERL5OPT="-M-indirect"
  46     perl -e 'my $y = new Coconut;' # warns
  47
  48 =head1 DESCRIPTION
  49
  50 When enabled (or disabled as some may prefer to say, since you actually turn it on by calling C<no indirect>), this pragma warns about indirect object syntax constructs that may have slipped into your code.
  51
  52 This syntax is now considered harmful, since its parsing has many quirks and its use is error prone (when C<swoosh> isn't defined, C<swoosh $x> actually compiles to C<< $x->swoosh >>).
  53 In L<http://www.shadowcat.co.uk/blog/matt-s-trout/indirect-but-still-fatal>, Matt S. Trout gives an example of an indirect construct that can cause a particularly bewildering error.
  54
  55 It currently does not warn for core functions (C<print>, C<say>, C<exec> or C<system>).
  56 This may change in the future, or may be added as optional features that would be enabled by passing options to C<unimport>.
  57
  58 This module is B<not> a source filter.
  59
  60 =cut
  61
  62 BEGIN {
  63  if ($ENV{PERL_INDIRECT_PM_DISABLE}) {
  64   *_tag = sub ($) { 1 };
  65   *I_THREADSAFE = sub () { 1 };
  66   *I_FORKSAFE   = sub () { 1 };
  67  } else {
  68   require XSLoader;
  69   XSLoader::load(__PACKAGE__, $VERSION);
  70  }
  71 }
  72
  73 =head1 METHODS
  74
  75 =head2 C<< unimport [ hook => $hook | ':fatal' ] >>
  76
  77 Magically called when C<no indirect @opts> is encountered.
  78 Turns the module on.
  79 The policy to apply depends on what is first found in C<@opts> :
  80
  81 =over 4
  82
  83 =item *
  84
  85 If it's the string C<':fatal'>, the compilation will croak on the first indirect syntax met.
  86
  87 =item *
  88
  89 If the key/value pair C<< hook => $hook >> comes first, C<$hook> will be called for each error with a string representation of the object as C<$_[0]>, the method name as C<$_[1]>, the current file as C<$_[2]> and the line number as C<$_[3]>.
  90 If and only if the object is actually a block, C<$_[0]> is assured to start by C<'{'>.
  91
  92 =item *
  93
  94 Otherwise, a warning will be emitted for each indirect construct.
  95
  96 =back
  97
  98 =cut
  99
 100 sub unimport {
 101  shift;
 102
 103  my $hook;
 104  while (@_) {
 105   my $arg = shift;
 106   if ($arg eq 'hook') {
 107    $hook = shift;
 108   } elsif ($arg eq ':fatal') {
 109    $hook = sub { die msg(@_) };
 110   }
 111   last if $hook;
 112  }
 113  $hook = sub { warn msg(@_) } unless defined $hook;
 114
 115  $^H |= 0x00020000;
 116  $^H{+(__PACKAGE__)} = _tag($hook);
 117
 118  ();
 119 }
 120
 121 =head2 C<import>
 122
 123 Magically called at each C<use indirect>. Turns the module off.
 124
 125 =cut
 126
 127 sub import {
 128  $^H{+(__PACKAGE__)} = undef;
 129  ();
 130 }
 131
 132 =head1 FUNCTIONS
 133
 134 =head2 C<msg $object, $method, $file, $line>
 135
 136 Returns the default error message generated by C<indirect> when an invalid construct is reported.
 137
 138 =cut
 139
 140 sub msg {
 141  my $obj = $_[0];
 142
 143  join ' ', "Indirect call of method \"$_[1]\" on",
 144            ($obj =~ /^\s*\{/ ? "a block" : "object \"$obj\""),
 145            "at $_[2] line $_[3].\n";
 146 };
 147
 148 =head1 CONSTANTS
 149
 150 =head2 C<I_THREADSAFE>
 151
 152 True iff the module could have been built with thread-safety features enabled.
 153
 154 =head2 C<I_FORKSAFE>
 155
 156 True iff this module could have been built with fork-safety features enabled.
 157 This will always be true except on Windows where it's false for perl 5.10.0 and below .
 158
 159 =head1 DIAGNOSTICS
 160
 161 =head2 C<Indirect call of method "%s" on object "%s" at %s line %d.>
 162
 163 The default warning/exception message thrown when an indirect call on an object is found.
 164
 165 =head2 C<Indirect call of method "%s" on a block at %s line %d.>
 166
 167 The default warning/exception message thrown when an indirect call on a block is found.
 168
 169 =head1 ENVIRONMENT
 170
 171 =head2 C<PERL_INDIRECT_PM_DISABLE>
 172
 173 If this environment variable is set to true when the pragma is used for the first time, the XS code won't be loaded and, although the C<'indirect'> lexical hint will be set to true in the scope of use, the pragma itself won't do anything.
 174 In this case, the pragma will always be considered to be thread-safe, and as such L</I_THREADSAFE> will be true.
 175 This is useful for disabling C<indirect> in production environments.
 176
 177 Note that clearing this variable after C<indirect> was loaded has no effect.
 178 If you want to reenable the pragma later, you also need to reload it by deleting the C<'indirect.pm'> entry from C<%INC>.
 179
 180 =head1 CAVEATS
 181
 182 The implementation was tweaked to work around several limitations of vanilla C<perl> pragmas : it's thread safe, and doesn't suffer from a C<perl 5.8.x-5.10.0> bug that causes all pragmas to propagate into C<require>d scopes.
 183
 184 C<meth $obj> (no semicolon) at the end of a file won't be seen as an indirect object syntax, although it will as soon as there is another token before the end (as in C<meth $obj;> or C<meth $obj 1>).
 185
 186 With 5.8 perls, the pragma does not propagate into C<eval STRING>.
 187 This is due to a shortcoming in the way perl handles the hints hash, which is addressed in perl 5.10.
 188
 189 The search for indirect method calls happens before constant folding.
 190 Hence C<my $x = new Class if 0> will be caught.
 191
 192 =head1 DEPENDENCIES
 193
 194 L<perl> 5.8.1.
 195
 196 L<XSLoader> (standard since perl 5.006).
 197
 198 =head1 AUTHOR
 199
 200 Vincent Pit, C<< <perl at profvince.com> >>, L<http://www.profvince.com>.
 201
 202 You can contact me by mail or on C<irc.perl.org> (vincent).
 203
 204 =head1 BUGS
 205
 206 Please report any bugs or feature requests to C<bug-indirect at rt.cpan.org>, or through the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=indirect>.
 207 I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.
 208
 209 =head1 SUPPORT
 210
 211 You can find documentation for this module with the perldoc command.
 212
 213     perldoc indirect
 214
 215 Tests code coverage report is available at L<http://www.profvince.com/perl/cover/indirect>.
 216
 217 =head1 ACKNOWLEDGEMENTS
 218
 219 Bram, for motivation and advices.
 220
 221 Andrew Main and Florian Ragwitz, for testing on real-life code and reporting issues.
 222
 223 =head1 COPYRIGHT & LICENSE
 224
 225 Copyright 2008,2009,2010 Vincent Pit, all rights reserved.
 226
 227 This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.
 228
 229 =cut
 230
 231 1; # End of indirect