X-Git-Url: http://git.vpit.fr/?p=perl%2Fmodules%2FThread-Cleanup.git;a=blobdiff_plain;f=t%2Flib%2FThread%2FCleanup%2FTestThreads.pm;fp=t%2Flib%2FThread%2FCleanup%2FTestThreads.pm;h=03b16ce6979e48fc8c2486c14a3bc227fd705235;hp=0000000000000000000000000000000000000000;hb=981090d572d766fbcccf048b3777e6fd1edc4fea;hpb=86915a65eed5d806e6c48b8b8fda1d3c4d990987

diff --git a/t/lib/Thread/Cleanup/TestThreads.pm b/t/lib/Thread/Cleanup/TestThreads.pm
new file mode 100644
index 0000000..03b16ce
--- /dev/null
+++ b/t/lib/Thread/Cleanup/TestThreads.pm
@@ -0,0 +1,50 @@
+package Thread::Cleanup::TestThreads;
+
+use strict;
+use warnings;
+
+use Config qw<%Config>;
+
+use VPIT::TestHelpers;
+
+sub diag {
+ require Test::More;
+ Test::More::diag($_) for @_;
+}
+
+sub import {
+ shift;
+
+ my $force = $ENV{PERL_THREAD_CLEANUP_TEST_THREADS} ? 1 : !1;
+ skip_all 'This perl wasn\'t built to support threads'
+                                                    unless $Config{useithreads};
+ skip_all 'perl 5.13.4 required to test thread safety'
+                                             unless $force or "$]" >= 5.013_004;
+
+ load_or_skip_all('threads',         $force ? '0' : '1.67', [ ]);
+ load_or_skip_all('threads::shared', $force ? '0' : '1.14', [ ]);
+
+ my %exports = (
+  spawn => \&spawn,
+ );
+
+ my $pkg = caller;
+ while (my ($name, $code) = each %exports) {
+  no strict 'refs';
+  *{$pkg.'::'.$name} = $code;
+ }
+}
+
+sub spawn {
+ local $@;
+ my @diag;
+ my $thread = eval {
+  local $SIG{__WARN__} = sub { push @diag, "Thread creation warning: @_" };
+  threads->create(@_);
+ };
+ push @diag, "Thread creation error: $@" if $@;
+ diag(@diag) if @diag;
+ return $thread ? $thread : ();
+}
+
+1;