use 5.006;

use strict;
use warnings;
use ExtUtils::MakeMaker;

use Config;
use File::Spec;

sub validate_exe {
 my ($name) = @_;

 my (@candidates, @args);
 if (File::Spec->file_name_is_absolute($name)) {
  # No need to look for args if the name is absolute.
  @candidates = $name;
 } else {
  (my $base, @args) = split ' ', $name;
  @candidates = map File::Spec->catfile($_, $base), File::Spec->path;
 }

 for my $path (@candidates) {
  my $command = MM->maybe_command($path);
  if (defined $command) {
   $command .= " @args" if @args;
   return $command;
  }
 }

 return;
}

sub check_exe {
 my ($desc, $arg_var, $config_var, $env_var) = @_;

 my $exe;

 for (@ARGV) {
  if (/^\Q$arg_var\E=(.*)/) {
   $exe = validate_exe($1);
   last if defined $exe;
  }
 }

 if (defined $exe) {
  print "Forcing the use of $exe as the $desc.\n";
 } else {
  print "Checking for a valid $desc in the PATH... ";
  $exe = validate_exe($Config{$config_var});
  # Only fall back to env if we cannot find the one used to build perl.
  if (not defined $exe and defined $ENV{$env_var}) {
   $exe = validate_exe($ENV{$env_var});
  }
  if (defined $exe) {
   print "$exe\n";
  } else {
   print "none\n";
  }
 }

 return $exe;
}

my $cc = check_exe('C compiler', 'CC', 'cc', 'CC');

my $ld;
if (defined $cc) {
 $ld = check_exe('linker', 'LD', 'ld', 'LD');
}

sub is_little_endian {
 my $order = $Config{byteorder};
 return 0 unless $order;
 my $len = length $order;
 if ($len > 8) {
  $order = substr $order, 0, 8;
  $len   = 8;
 }
 return $order eq (join '', 1 .. $len);
}

my %PARAMS;
my @DEFINES;

if (defined $cc and defined $ld) {
 $PARAMS{C}  = [ 'Util.c' ];
 $PARAMS{XS} = { 'Util.xs' => 'Util.c' };
 $PARAMS{CC} = $cc;
 $PARAMS{LD} = $ld;

 my $unit = { bits => 8, size => 1 };
 if (not is_little_endian()) {
  print "Forcing unit size of 8 on non-little-endian systems.\n";
 } else {
  print "Checking unit size in bits... ";
  my $align = $Config{alignbytes} || 1;
  my @bits = (8, 16, 32, 64);
  for my $bits (@bits) {
   my $size = $Config{"u${bits}size"};
   next unless $size;
   $unit = { bits => $bits, size => $size } if $size && $size <= $align;
  }
  print $unit->{bits},
                " (actually $unit->{size} bytes for $align bytes alignment).\n";
 }

 my $bits = $unit->{bits};
 push @DEFINES, '-DBV_UNIT="' . ($Config{"u${bits}type"} || "U$bits") . '"';
 push @DEFINES, "-DSVU_SIZE=$bits";
} else {
 $PARAMS{C}      = [ ];
 $PARAMS{XS}     = { };
 $PARAMS{OBJECT} = '';
}

$PARAMS{DEFINE} = join ' ', @DEFINES if @DEFINES;

my $dist = 'Scalar-Vec-Util';

(my $name = $dist) =~ s{-}{::}g;

(my $file = $dist) =~ s{-}{/}g;
$file = "lib/$file.pm";

my %PREREQ_PM = (
 'Exporter' => 0,
 'Carp'     => 0,
 'XSLoader' => 0,
 'base'     => 0,
);

my %BUILD_REQUIRES = (
 'Config'              => 0,
 'ExtUtils::MakeMaker' => 0,
 'File::Spec'          => 0,
 'Test::More'          => 0,
 %PREREQ_PM,
);

my %META = (
 configure_requires => {
  'Config'              => 0,
  'ExtUtils::MakeMaker' => 0,
  'File::Spec'          => 0,
 },
 build_requires => {
  %BUILD_REQUIRES,
 },
 dynamic_config => 1,
 resources => {
  bugtracker => "http://rt.cpan.org/Dist/Display.html?Name=$dist",
  homepage   => "http://search.cpan.org/dist/$dist/",
  license    => 'http://dev.perl.org/licenses/',
  repository => "http://git.profvince.com/?p=perl%2Fmodules%2F$dist.git",
 },
);

WriteMakefile(
 NAME             => $name,
 AUTHOR           => 'Vincent Pit <perl@profvince.com>',
 LICENSE          => 'perl',
 VERSION_FROM     => $file,
 ABSTRACT_FROM    => $file,
 PL_FILES         => {},
 BUILD_REQUIRES   => \%BUILD_REQUIRES,
 PREREQ_PM        => \%PREREQ_PM,
 MIN_PERL_VERSION => '5.006',
 META_MERGE       => \%META,
 dist             => {
  PREOP    => "pod2text -u $file > \$(DISTVNAME)/README",
  COMPRESS => 'gzip -9f', SUFFIX => 'gz'
 },
 clean            => {
  FILES => "$dist-* *.gcov *.gcda *.gcno cover_db Debian_CPANTS.txt*"
 },
 %PARAMS,
);

1;

package MY;

sub postamble {
 my $cv = join ' -coverage ', 'cover',
                            qw<statement branch condition path subroutine time>;
 <<POSTAMBLE;
cover test_cover:
	$cv -test
POSTAMBLE
}