use 5.006;

use strict;
use warnings;
use ExtUtils::MakeMaker;

use Config;
use File::Spec;

sub validate_exe {
 my ($name, $preferred_path) = @_;

 my (@candidates, @args);
 if (File::Spec->file_name_is_absolute($name)) {
  # No need to look for args if the name is absolute.
  @candidates = $name;
 } else {
  my @path;
  if (defined $preferred_path) {
   @path = ($preferred_path, grep { $_ ne $preferred_path } File::Spec->path);
  } else {
   @path = File::Spec->path;
  }

  (my $base, @args) = split ' ', $name;
  for my $path_entry (@path) {
   my ($vol, $dir, $file) = File::Spec->splitpath($path_entry, 1);
   next if defined $file and length $file;
   push @candidates, File::Spec->catpath($vol, $dir, $base);
  }
 }

 for my $path (@candidates) {
  my $command = MM->maybe_command($path);
  if (defined $command) {
   $command .= " @args" if @args;
   return $command;
  }
 }

 return;
}

sub check_exe {
 my (%args) = @_;

 my $desc           = delete $args{desc};
 my $arg_var        = delete $args{arg_var};
 my $tries          = delete $args{try};
 my $preferred_path = delete $args{preferred_path};

 my $exe;

 for (@ARGV) {
  if (/^\Q$arg_var\E=(.*)/) {
   $exe = validate_exe($1, $preferred_path);
   last if defined $exe;
  }
 }

 if (defined $exe) {
  print "Forcing the use of $exe as the $desc.\n";
 } else {
  print "Checking for a valid $desc in the PATH... ";
  for my $try (@$tries) {
   next unless defined $try;
   $exe = validate_exe($try, $preferred_path);
   last if defined $exe;
  }
  if (defined $exe) {
   print "$exe\n";
  } else {
   print "none\n";
  }
 }

 return $exe;
}

sub filter_argv {
 my ($var, $code) = @_;

 my $ret;

 for my $i (0 .. $#ARGV) {
  my $arg = $ARGV[$i];
  if ($arg =~ /^\Q$var\E=(.*)/) {
   my $val = $1;
   $ret = $code->($val);
   $ARGV[$i] = undef;
   last if $ret;
  }
 }

 @ARGV = grep defined, @ARGV;

 return $ret;
}

my ($cc, $ld);
my $pp = filter_argv PP => sub {
 my ($val) = @_;
 return (do { no warnings 'numeric'; int $val } or $val =~ /^(?:y|yes)$/i)
        ? 1 : 0;
};
if ($pp) {
 print "Forcing the pure-Perl implementation from the arguments passed to Makefile.PL.\n";
} else {
 $cc = check_exe(
  desc    => 'C compiler',
  arg_var => 'CC',
  try     => [ $Config{cc}, $ENV{CC}, 'cc' ],
 );
 if (defined $cc) {
  my ($vol, $dir, $file) = File::Spec->splitpath($cc);
  my $preferred_path = File::Spec->catpath($vol, $dir, '');
  $ld = check_exe(
   desc           => 'linker',
   arg_var        => 'LD',
   try            => [ $Config{ld}, $ENV{LD}, 'ld' ],
   preferred_path => $preferred_path,
  );
 }
}

sub is_little_endian {
 my $order = $Config{byteorder};
 return 0 unless $order;
 my $len = length $order;
 if ($len > 8) {
  $order = substr $order, 0, 8;
  $len   = 8;
 }
 return $order eq (join '', 1 .. $len);
}

my %PARAMS;
my @DEFINES;

if (defined $cc and defined $ld) {
 $PARAMS{C}  = [ 'Util.c' ];
 $PARAMS{XS} = { 'Util.xs' => 'Util.c' };
 $PARAMS{CC} = $cc;
 $PARAMS{LD} = $ld;

 my $type = filter_argv UNIT => sub { return $_[0] };
 if (defined $type) {
  print "Forcing '$type' as the unit.\n";
  push @DEFINES, '-DBV_UNIT="' . $type . '"';
 } else {
  my $bits = 8;
  if (not is_little_endian()) {
   print "Forcing unit size of 8 on non-little-endian systems.\n";
  } else {
   print "Checking unit size in bits... ";
   my $size  = 1;
   my $align = $Config{alignbytes} || 1;
   my @units = (8, 16, 32, 64);
   for my $unit (@units) {
    my $unit_size = $Config{"u${unit}size"};
    if ($unit_size and $unit_size <= $align) {
     $bits = $unit;
     $size = $unit_size;
    }
   }
   print "$bits (actually $size bytes for $align bytes alignment).\n";
  }
  push @DEFINES, '-DBV_UNIT="' . ($Config{"u${bits}type"} || "U$bits") . '"';
  push @DEFINES, "-DSVU_SIZE=$bits";
 }
} else {
 $PARAMS{C}      = [ ];
 $PARAMS{XS}     = { };
 $PARAMS{OBJECT} = '';
 print "Falling back to the pure-Perl implementation.\n";
}

$PARAMS{DEFINE} = join ' ', @DEFINES if @DEFINES;

my $dist = 'Scalar-Vec-Util';

(my $name = $dist) =~ s{-}{::}g;

(my $file = $dist) =~ s{-}{/}g;
$file = "lib/$file.pm";

my %PREREQ_PM = (
 'Exporter' => 0,
 'Carp'     => 0,
 'XSLoader' => 0,
 'base'     => 0,
);

my %BUILD_REQUIRES = (
 'Config'              => 0,
 'ExtUtils::MakeMaker' => 0,
 'File::Spec'          => 0,
 'Test::More'          => 0,
 %PREREQ_PM,
);

my %META = (
 configure_requires => {
  'Config'              => 0,
  'ExtUtils::MakeMaker' => 0,
  'File::Spec'          => 0,
 },
 build_requires => {
  %BUILD_REQUIRES,
 },
 dynamic_config => 1,
 resources => {
  bugtracker => "http://rt.cpan.org/Dist/Display.html?Name=$dist",
  homepage   => "http://search.cpan.org/dist/$dist/",
  license    => 'http://dev.perl.org/licenses/',
  repository => "http://git.profvince.com/?p=perl%2Fmodules%2F$dist.git",
 },
);

WriteMakefile(
 NAME             => $name,
 AUTHOR           => 'Vincent Pit <perl@profvince.com>',
 LICENSE          => 'perl',
 VERSION_FROM     => $file,
 ABSTRACT_FROM    => $file,
 PL_FILES         => {},
 BUILD_REQUIRES   => \%BUILD_REQUIRES,
 PREREQ_PM        => \%PREREQ_PM,
 MIN_PERL_VERSION => '5.006',
 META_MERGE       => \%META,
 dist             => {
  PREOP    => "pod2text -u $file > \$(DISTVNAME)/README",
  COMPRESS => 'gzip -9f', SUFFIX => 'gz'
 },
 clean            => {
  FILES => "$dist-* *.gcov *.gcda *.gcno cover_db Debian_CPANTS.txt*"
 },
 %PARAMS,
);

1;

package MY;

sub postamble {
 my $cv = join ' -coverage ', 'cover',
                            qw<statement branch condition path subroutine time>;
 <<POSTAMBLE;
cover test_cover:
	$cv -test
POSTAMBLE
}