X-Git-Url: http://git.vpit.fr/?p=perl%2Fmodules%2FLinux-SysInfo.git;a=blobdiff_plain;f=t%2Flib%2FLinux%2FSysInfo%2FTestThreads.pm;fp=t%2Flib%2FLinux%2FSysInfo%2FTestThreads.pm;h=37a88c99463f56f1bd193bf38b7b0b9f91de93b8;hp=0000000000000000000000000000000000000000;hb=bea1d11f74a387b85e2daa0a684466ed65d7ea71;hpb=df2d2239c4e52ed9bf6891f03d6a3bb8e65a1297

diff --git a/t/lib/Linux/SysInfo/TestThreads.pm b/t/lib/Linux/SysInfo/TestThreads.pm
new file mode 100644
index 0000000..37a88c9
--- /dev/null
+++ b/t/lib/Linux/SysInfo/TestThreads.pm
@@ -0,0 +1,49 @@
+package Linux::SysInfo::TestThreads;
+
+use strict;
+use warnings;
+
+use Config qw<%Config>;
+
+use VPIT::TestHelpers;
+
+sub diag {
+ require Test::More;
+ Test::More::diag($_) for @_;
+}
+
+sub import {
+ shift;
+
+ my $force = $ENV{PERL_LINUX_SYSINFO_TEST_THREADS} ? 1 : !1;
+ skip_all 'This perl wasn\'t built to support threads'
+                                                    unless $Config{useithreads};
+ skip_all 'perl 5.13.4 required to test thread safety'
+                                             unless $force or "$]" >= 5.013_004;
+
+ load_or_skip_all('threads', $force ? '0' : '1.67', [ ]);
+
+ my %exports = (
+  spawn => \&spawn,
+ );
+
+ my $pkg = caller;
+ while (my ($name, $code) = each %exports) {
+  no strict 'refs';
+  *{$pkg.'::'.$name} = $code;
+ }
+}
+
+sub spawn {
+ local $@;
+ my @diag;
+ my $thread = eval {
+  local $SIG{__WARN__} = sub { push @diag, "Thread creation warning: @_" };
+  threads->create(@_);
+ };
+ push @diag, "Thread creation error: $@" if $@;
+ diag(@diag) if @diag;
+ return $thread ? $thread : ();
+}
+
+1;