From: Vincent Pit <perl@profvince.com>
Date: Wed, 11 Nov 2015 13:43:09 +0000 (-0200)
Subject: Move and improve the subclass validation logic into a new helper module
X-Git-Tag: v1.16~14
X-Git-Url: http://git.vpit.fr/?a=commitdiff_plain;h=63def84a00e5e8260b0456e0dfc716d35aab435a;p=perl%2Fmodules%2FTest-Valgrind.git

Move and improve the subclass validation logic into a new helper module
---

diff --git a/MANIFEST b/MANIFEST
index 6d572f0..3421317 100644
--- a/MANIFEST
+++ b/MANIFEST
@@ -27,6 +27,7 @@ lib/Test/Valgrind/Session.pm
 lib/Test/Valgrind/Suppressions.pm
 lib/Test/Valgrind/Tool.pm
 lib/Test/Valgrind/Tool/memcheck.pm
+lib/Test/Valgrind/Util.pm
 samples/map.pl
 samples/xml-output-protocol4.txt
 samples/xml-output.txt
diff --git a/lib/Test/Valgrind/Action.pm b/lib/Test/Valgrind/Action.pm
index fbdffe6..ca3fbd2 100644
--- a/lib/Test/Valgrind/Action.pm
+++ b/lib/Test/Valgrind/Action.pm
@@ -23,6 +23,8 @@ Actions are called each time a tool encounter an error and decide what to do wit
 
 =cut
 
+use Test::Valgrind::Util;
+
 use base qw<Test::Valgrind::Component Test::Valgrind::Carp>;
 
 =head1 METHODS
@@ -43,11 +45,10 @@ sub new {
  my %args = @_;
 
  if ($class eq __PACKAGE__) {
-  my $action = delete $args{action} || 'Test';
-  $action =~ s/[^\w:]//g;
-  $action = __PACKAGE__ . "::$action" if $action !~ /::/;
-  $class->_croak("Couldn't load action $action: $@")
-                                               unless eval "require $action; 1";
+  my ($action, $msg) = Test::Valgrind::Util::validate_subclass(
+   $args{action} || 'Test',
+  );
+  $class->_croak($msg) unless defined $action;
   return $action->new(%args);
  }
 
diff --git a/lib/Test/Valgrind/Command.pm b/lib/Test/Valgrind/Command.pm
index a305ed6..be786e9 100644
--- a/lib/Test/Valgrind/Command.pm
+++ b/lib/Test/Valgrind/Command.pm
@@ -24,6 +24,8 @@ They should also provide a default setup for generating suppressions.
 
 =cut
 
+use Test::Valgrind::Util;
+
 use base qw<Test::Valgrind::Carp>;
 
 =head1 METHODS
@@ -48,10 +50,10 @@ sub new {
 
  my %args = @_;
 
- if ($class eq __PACKAGE__ and my $cmd = delete $args{command}) {
-  $cmd =~ s/[^\w:]//g;
-  $cmd = __PACKAGE__ . "::$cmd" if $cmd !~ /::/;
-  $class->_croak("Couldn't load command $cmd: $@") unless eval "require $cmd;1";
+ my $cmd = delete $args{command};
+ if ($class eq __PACKAGE__ and defined $cmd) {
+  ($cmd, my $msg) = Test::Valgrind::Util::validate_subclass($cmd);
+  $class->_croak($msg) unless defined $cmd;
   return $cmd->new(%args);
  }
 
diff --git a/lib/Test/Valgrind/Tool.pm b/lib/Test/Valgrind/Tool.pm
index bb7adda..0961fb8 100644
--- a/lib/Test/Valgrind/Tool.pm
+++ b/lib/Test/Valgrind/Tool.pm
@@ -24,6 +24,8 @@ They are expected to function both in suppressions generation and in analysis mo
 
 =cut
 
+use Test::Valgrind::Util;
+
 use base qw<Test::Valgrind::Component Test::Valgrind::Carp>;
 
 =head1 METHODS
@@ -55,10 +57,10 @@ sub new {
  my %args = @_;
 
  if ($class eq __PACKAGE__) {
-  my $tool = delete $args{tool} || 'memcheck';
-  $tool =~ s/[^\w:]//g;
-  $tool = __PACKAGE__ . "::$tool" if $tool !~ /::/;
-  $class->_croak("Couldn't load tool $tool: $@") unless eval "require $tool; 1";
+  my ($tool, $msg) = Test::Valgrind::Util::validate_subclass(
+   delete $args{tool} || 'memcheck',
+  );
+  $class->_croak($msg) unless defined $tool;
   return $tool->new(%args);
  }
 
diff --git a/lib/Test/Valgrind/Util.pm b/lib/Test/Valgrind/Util.pm
new file mode 100644
index 0000000..441ce69
--- /dev/null
+++ b/lib/Test/Valgrind/Util.pm
@@ -0,0 +1,88 @@
+package Test::Valgrind::Util;
+
+use strict;
+use warnings;
+
+=head1 NAME
+
+Test::Valgrind::Util - Utility routines for Test::Valgrind.
+
+=head1 VERSION
+
+Version 1.15
+
+=cut
+
+our $VERSION = '1.15';
+
+=head1 DESCRIPTION
+
+This module contains some helpers used by Test::Valgrind.
+It is not really designed to be used anywhere else.
+
+=head1 FUNCTIONS
+
+=head2 C<validate_subclass>
+
+    my ($validated_type, $error_msg) = validate_subclass($type);
+
+Try to interpret C<$type> as a subclass of the caller package, and load it if its C<@ISA> is empty.
+Returns the validated type, or C<undef> and the relevant error message.
+
+=cut
+
+sub validate_subclass {
+ my ($type) = @_;
+
+ my $base = (caller 0)[0];
+
+ $type =~ s/[^A-Za-z0-9_:]//g;
+ $type =  "${base}::$type" if $type !~ /::/;
+
+ my $stash = do { no strict 'refs'; \%{"${type}::"} };
+ my $ISA   = ($stash && $stash->{ISA}) ? *{$stash->{ISA}}{ARRAY} : undef;
+
+ unless ($ISA and @$ISA >= 1) {
+  local $@;
+  eval "require $type; 1" or return (undef, "Could not load subclass: $@");
+ }
+
+ return (undef, "$type is not a subclass of $base") unless $type->isa($base);
+
+ return $type;
+}
+
+=head1 EXPORT
+
+This module does not export anything.
+
+=head1 SEE ALSO
+
+L<Test::Valgrind>.
+
+=head1 AUTHOR
+
+Vincent Pit, C<< <perl at profvince.com> >>, L<http://www.profvince.com>.
+
+You can contact me by mail or on C<irc.perl.org> (vincent).
+
+=head1 BUGS
+
+Please report any bugs or feature requests to C<bug-test-valgrind at rt.cpan.org>, or through the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Test-Valgrind>.
+I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.
+
+=head1 SUPPORT
+
+You can find documentation for this module with the perldoc command.
+
+    perldoc Test::Valgrind::Component
+
+=head1 COPYRIGHT & LICENSE
+
+Copyright 2015 Vincent Pit, all rights reserved.
+
+This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.
+
+=cut
+
+1; # End of Test::Valgrind::Util