package LaTeX::TikZ::Set::Rectangle;

use strict;
use warnings;

=head1 NAME

LaTeX::TikZ::Set::Rectangle - A set object representing a rectangle.

=head1 VERSION

Version 0.01

=cut

our $VERSION = '0.01';

use Any::Moose;

with 'LaTeX::TikZ::Set::Op';

has 'from' => (
 is       => 'ro',
 does     => 'LaTeX::TikZ::Point',
 required => 1,
);

has 'to' => (
 is       => 'ro',
 does     => 'LaTeX::TikZ::Point',
 required => 1,
);

has 'width' => (
 is  => 'ro',
 isa => 'Num',
);

has 'height' => (
 is  => 'ro',
 isa => 'Num',
);

sub path {
 my $set = shift;

 $set->from->path(@_) . ' rectangle ' . $set->to->path(@_);
}

around 'BUILDARGS' => sub {
 my $orig  = shift;
 my $class = shift;

 my $meta = __PACKAGE__->meta;
 my $tc1  = $meta->find_attribute_by_name('from')->type_constraint;
 my $tc2  = $meta->find_attribute_by_name('to')->type_constraint;

 if (@_ == 2 and $tc1->check($_[0]) and $tc2->check($_[1])) {
  @_ = (
   from => $_[0],
   to   => $_[1],
  );
 } else {
  my %args = @_;
  if (not exists $args{to}
      and exists $args{from} and $tc1->check($args{from})) {
   confess(<<'   MSG') unless exists $args{width} and exists $args{height};
Attributes 'width' and 'height' are required when 'to' was not given
   MSG
   $meta->find_attribute_by_name($_)->type_constraint->assert_valid($args{$_})
                                                           for qw/width height/;
   $args{to} = $args{from}->translate($args{width}, $args{height});
   @_ = %args;
  }
 }

 $class->$orig(@_);
};

use LaTeX::TikZ::API rectangle => sub {
 shift;
 my ($p, $q) = @_;

 my $is_relative = !blessed($q) && ref($q) eq 'ARRAY';

 __PACKAGE__->new(
  from => $p,
  ($is_relative ? (width => $q->[0], height => $q->[1]) : (to => $q)),
 );
};

__PACKAGE__->meta->make_immutable;

=head1 AUTHOR

Vincent Pit, C<< <perl at profvince.com> >>, L<http://www.profvince.com>.

You can contact me by mail or on C<irc.perl.org> (vincent).

=head1 BUGS

Please report any bugs or feature requests to C<bug-latex-tikz at rt.cpan.org>, or through the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=LaTeX-TikZ>.
I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.

=head1 SUPPORT

You can find documentation for this module with the perldoc command.

    perldoc LaTeX::TikZ

=head1 COPYRIGHT & LICENSE

Copyright 2010 Vincent Pit, all rights reserved.

This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.

=cut

1; # End of LaTeX::TikZ::Set::Rectangle
