package LaTeX::TikZ::Set::Path;

use strict;
use warnings;

=head1 NAME

LaTeX::TikZ::Set::Path - A set object representing a path.

=head1 VERSION

Version 0.01

=cut

our $VERSION = '0.01';

use Any::Moose;
use Any::Moose 'Util::TypeConstraints'
               => [ qw/subtype as where find_type_constraint/ ];

with qw(
 LaTeX::TikZ::Set::Op
 LaTeX::TikZ::Set::Mutable
);

subtype 'LaTeX::TikZ::Set::Path::Elements'
     => as 'Object'
     => where { $_->does('LaTeX::TikZ::Set::Op') };

has '_ops' => (
 is       => 'ro',
 isa      => 'Maybe[ArrayRef[LaTeX::TikZ::Set::Path::Elements]]',
 init_arg => 'ops',
 default  => sub { [ ] },
);

sub ops { @{$_[0]->_ops} }

my $ltspe_tc = find_type_constraint('LaTeX::TikZ::Set::Path::Elements');

sub add {
 my $set = shift;

 $ltspe_tc->assert_valid($_) for @_;

 push @{$set->_ops}, @_;

 $set;
}

sub path {
 my $set = shift;

 join ' ', map $_->path(@_), $set->ops;
}

use LaTeX::TikZ::API path => sub {
 shift;

 __PACKAGE__->new(ops => \@_);
};

__PACKAGE__->meta->make_immutable;

=head1 AUTHOR

Vincent Pit, C<< <perl at profvince.com> >>, L<http://www.profvince.com>.

You can contact me by mail or on C<irc.perl.org> (vincent).

=head1 BUGS

Please report any bugs or feature requests to C<bug-latex-tikz at rt.cpan.org>, or through the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=LaTeX-TikZ>.
I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.

=head1 SUPPORT

You can find documentation for this module with the perldoc command.

    perldoc LaTeX::TikZ

=head1 COPYRIGHT & LICENSE

Copyright 2010 Vincent Pit, all rights reserved.

This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.

=cut

1; # End of LaTeX::TikZ::Set::Path
