package LaTeX::TikZ::Mod::Pattern;

use strict;
use warnings;

=head1 NAME

LaTeX::TikZ::Mod::Pattern - A modifier that fills a closed path with a pattern.

=head1 VERSION

Version 0.01

=cut

our $VERSION = '0.01';

use Any::Moose;

with 'LaTeX::TikZ::Mod';

has 'template' => (
 is       => 'ro',
 isa      => 'Str',
 required => 1,
);

has '_cache' => (
 is       => 'ro',
 isa      => 'HashRef',
 init_arg => undef,
 default  => sub { +{ } },
);

sub name {
 my ($pat, $tikz) = @_;

 my $cache = $pat->_cache->{$tikz->id};
 confess('Template not yet declared') unless defined $cache;

 $cache->[0];
}

my $id = 'a';

my %handlers = (
 name  => sub { $_[0]->name($_[1]) },
 width => sub { sprintf '%0.1fpt', $_[1]->thickness($_[2]) },
);

sub tag { ref $_[0] }

sub cover { 1 }

sub declare {
 my ($pat, $tikz) = @_;

 my $tikz_id = $tikz->id;
 my $cache   = $pat->_cache->{$tikz_id};
 return $cache->[1] if defined $cache;
 $cache = $pat->_cache->{$tikz_id} = [ ];

 $cache->[0] = 'pat' . $id++;

 my $template = $pat->template;
 $template =~ s!#([^#]+)#!
  my ($command, @opts) = split /=/, $1, 2;
  @opts = split /,/, $opts[0] if @opts;
  $handlers{lc $command}->($pat, $tikz, @opts);
 !ge;
 $cache->[1] = $template;
}

sub apply { 'fill', 'pattern=' . $_[0]->name($_[1]) }

__PACKAGE__->meta->make_immutable;

=head1 AUTHOR

Vincent Pit, C<< <perl at profvince.com> >>, L<http://www.profvince.com>.

You can contact me by mail or on C<irc.perl.org> (vincent).

=head1 BUGS

Please report any bugs or feature requests to C<bug-latex-tikz at rt.cpan.org>, or through the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=LaTeX-TikZ>.
I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.

=head1 SUPPORT

You can find documentation for this module with the perldoc command.

    perldoc LaTeX::TikZ

=head1 COPYRIGHT & LICENSE

Copyright 2010 Vincent Pit, all rights reserved.

This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.

=cut

1; # End of LaTeX::TikZ::Mod::Pattern
