t/59-unwind-threads.t

   1 #!perl -T
   2
   3 use strict;
   4 use warnings;
   5
   6 sub skipall {
   7  my ($msg) = @_;
   8  require Test::More;
   9  Test::More::plan(skip_all => $msg);
  10 }
  11
  12 use Config qw<%Config>;
  13
  14 BEGIN {
  15  my $force = $ENV{PERL_SCOPE_UPPER_TEST_THREADS} ? 1 : !1;
  16  my $t_v   = $force ? '0' : '1.67';
  17  skipall 'This perl wasn\'t built to support threads'
  18                                                     unless $Config{useithreads};
  19  skipall 'perl 5.13.4 required to test thread safety'
  20                                               unless $force or "$]" >= 5.013004;
  21  skipall "threads $t_v required to test thread safety"
  22                                               unless eval "use threads $t_v; 1";
  23 }
  24
  25 use Test::More;
  26
  27 use Scope::Upper qw<unwind UP SU_THREADSAFE>;
  28
  29 my $num;
  30
  31 BEGIN {
  32  skipall 'This Scope::Upper isn\'t thread safe' unless SU_THREADSAFE;
  33  plan tests => ($num = 30);
  34  defined and diag "Using threads $_" for $threads::VERSION;
  35  if (eval "use Time::HiRes; 1") {
  36   defined and diag "Using Time::HiRes $_" for $Time::HiRes::VERSION;
  37   *usleep = \&Time::HiRes::usleep;
  38  } else {
  39   diag 'Using fallback usleep';
  40   *usleep = sub {
  41    my $s = int($_[0] / 2.5e5);
  42    sleep $s if $s;
  43   };
  44  }
  45 }
  46
  47 our $z;
  48
  49 sub up1 {
  50  my $tid  = threads->tid();
  51  local $z = $tid;
  52  my $p    = "[$tid] up1";
  53
  54  usleep rand(1e6);
  55
  56  my @res = (
  57   -1,
  58   sub {
  59    my @dummy = (
  60     999,
  61     sub {
  62      my $foo = unwind $tid .. $tid + 2 => UP;
  63      fail "$p: not reached";
  64     }->()
  65    );
  66    fail "$p: not reached";
  67   }->(),
  68   -2
  69  );
  70
  71  is_deeply \@res, [ -1, $tid .. $tid + 2, -2 ], "$p: unwinded correctly";
  72 }
  73
  74 $_->join for map threads->create(\&up1), 1 .. $num;