t/31-array.t

   1 #!perl -T
   2
   3 use strict;
   4 use warnings;
   5
   6 use Test::More tests => 2 * 25 + 9 + 1;
   7
   8 use Variable::Magic qw/cast dispell VMG_COMPAT_ARRAY_PUSH_NOLEN VMG_COMPAT_ARRAY_UNSHIFT_NOLEN_VOID VMG_COMPAT_ARRAY_UNDEF_CLEAR/;
   9
  10 use lib 't/lib';
  11 use Variable::Magic::TestWatcher;
  12
  13 my $wiz = init
  14         [ qw/get set len clear free copy dup local fetch store exists delete/ ],
  15         'array';
  16
  17 my @n = map { int rand 1000 } 1 .. 5;
  18 my @a = @n;
  19
  20 check { cast @a, $wiz } { }, 'cast';
  21
  22 my $b;
  23 check { $b = $a[2] } { }, 'assign element to';
  24 is $b, $n[2], 'array: assign element to correctly';
  25
  26 my @b;
  27 check { @b = @a } { len => 1 }, 'assign to';
  28 is_deeply \@b, \@n, 'array: assign to correctly';
  29
  30 check { $b = "X@{a}Y" } { len => 1 }, 'interpolate';
  31 is $b, "X@{n}Y", 'array: interpolate correctly';
  32
  33 check { $b = \@a } { }, 'reference';
  34
  35 check { @b = @a[2 .. 4] } { }, 'slice';
  36 is_deeply \@b, [ @n[2 .. 4] ], 'array: slice correctly';
  37
  38 check { @a = qw/a b d/ } { set => 3, clear => 1 }, 'assign';
  39
  40 check { $a[2] = 'c' } { }, 'assign old element';
  41
  42 check { $a[3] = 'd' } { set => 1 }, 'assign new element';
  43
  44 check { push @a, 'x'; () }
  45           { set => 1, (len => 1) x !VMG_COMPAT_ARRAY_PUSH_NOLEN },'push (void)';
  46 check { $b = push @a, 'y' }
  47        { set => 1, (len => 1) x !VMG_COMPAT_ARRAY_PUSH_NOLEN }, 'push (scalar)';
  48
  49 check { $b = pop @a } { set => 1, len => 1 }, 'pop';
  50 is $b, 'y', 'array: pop correctly';
  51
  52 check { unshift @a, 'z'; () }
  53                 { set => 1, (len => 1) x !VMG_COMPAT_ARRAY_UNSHIFT_NOLEN_VOID },
  54                 'unshift (void)';
  55
  56 check { $b = unshift @a, 't' } { set => 1, len => 1 }, 'unshift (scalar)';
  57
  58 check { $b = shift @a } { set => 1, len => 1 }, 'shift';
  59 is $b, 't', 'array: shift correctly';
  60
  61 check { $b = @a } { len => 1 }, 'length @';
  62 is $b, 6, 'array: length @ correctly';
  63
  64 check { $b = $#a } { len => 1 }, 'length $#';
  65 is $b, 5, 'array: length $# correctly';
  66
  67 check { my $i; @a = map ++$i, @a; () } { set => 6, len => 1, clear => 1}, 'map';
  68
  69 check { @b = grep { $_ >= 4 } @a } { len => 1 }, 'grep';
  70 is_deeply \@b, [ 4 .. 6 ], 'array: grep correctly';
  71
  72 check { 1 for @a } { len => 6 + 1 }, 'for';
  73
  74 check {
  75  my @b = @n;
  76  check { cast @b, $wiz } { }, 'cast 2';
  77 } { free => 1 }, 'scope end';
  78
  79 check { undef @a } +{ (clear => 1) x VMG_COMPAT_ARRAY_UNDEF_CLEAR }, 'undef';
  80
  81 check { dispell @a, $wiz } { }, 'dispell';