indirect.pm

   1 package indirect;
   2
   3 use 5.008001;
   4
   5 use strict;
   6 use warnings;
   7
   8 =head1 NAME
   9
  10 indirect - Lexically warn about using the indirect method call syntax.
  11
  12 =head1 VERSION
  13
  14 Version 0.25
  15
  16 =cut
  17
  18 our $VERSION;
  19 BEGIN {
  20  $VERSION = '0.25';
  21 }
  22
  23 =head1 SYNOPSIS
  24
  25 In a script :
  26
  27     no indirect;               # lexically enables the pragma
  28     my $x = new Apple 1, 2, 3; # warns
  29     {
  30      use indirect;     # lexically disables the pragma
  31      my $y = new Pear; # legit, does not warn
  32      {
  33       # lexically specify an hook called for each indirect construct
  34       no indirect hook => sub {
  35        die "You really wanted $_[0]\->$_[1] at $_[2]:$_[3]"
  36       };
  37       my $z = new Pineapple 'fresh'; # croaks 'You really wanted...'
  38      }
  39     }
  40     try { ... }; # warns if try() hasn't been declared in this package
  41
  42     no indirect 'fatal';     # or ':fatal', 'FATAL', ':Fatal' ...
  43     if (defied $foo) { ... } # croaks, note the typo
  44
  45 Global uses :
  46
  47     # Globally enable the pragma from the command-line
  48     perl -M-indirect=global -e 'my $x = new Banana;' # warns
  49
  50     # Globally enforce the pragma each time perl is executed
  51     export PERL5OPT="-M-indirect=global,fatal"
  52     perl -e 'my $y = new Coconut;' # croaks
  53
  54 =head1 DESCRIPTION
  55
  56 When enabled, this pragma warns about indirect method calls that are present in your code.
  57
  58 The indirect syntax is now considered harmful, since its parsing has many quirks and its use is error prone : when the subroutine C<foo> has not been declared in the current package, C<foo $x> actually compiles to C<< $x->foo >>, and C<< foo { key => 1 } >> to C<< 'key'->foo(1) >>.
  59 In L<http://www.shadowcat.co.uk/blog/matt-s-trout/indirect-but-still-fatal>, Matt S. Trout gives an example of an undesirable indirect method call on a block that can cause a particularly bewildering error.
  60
  61 This pragma currently does not warn for core functions (C<print>, C<say>, C<exec> or C<system>).
  62 This may change in the future, or may be added as optional features that would be enabled by passing options to C<unimport>.
  63
  64 This module is B<not> a source filter.
  65
  66 =cut
  67
  68 BEGIN {
  69  if ($ENV{PERL_INDIRECT_PM_DISABLE}) {
  70   *_tag = sub ($) { 1 };
  71   *I_THREADSAFE = sub () { 1 };
  72   *I_FORKSAFE   = sub () { 1 };
  73  } else {
  74   require XSLoader;
  75   XSLoader::load(__PACKAGE__, $VERSION);
  76  }
  77 }
  78
  79 =head1 METHODS
  80
  81 =head2 C<< unimport [ 'global', hook => $hook | 'fatal' ] >>
  82
  83 Magically called when C<no indirect @opts> is encountered.
  84 Turns the module on.
  85 The policy to apply depends on what is first found in C<@opts> :
  86
  87 =over 4
  88
  89 =item *
  90
  91 If it is a string that matches C</^:?fatal$/i>, the compilation will croak when the first indirect method call is found.
  92
  93 =item *
  94
  95 If the key/value pair C<< hook => $hook >> comes first, C<$hook> will be called for each error with a string representation of the object as C<$_[0]>, the method name as C<$_[1]>, the current file as C<$_[2]> and the line number as C<$_[3]>.
  96 If and only if the object is actually a block, C<$_[0]> is assured to start by C<'{'>.
  97
  98 =item *
  99
 100 If none of C<fatal> and C<hook> are specified, a warning will be emitted for each indirect method call.
 101
 102 =item *
 103
 104 If C<@opts> contains a string that matches C</^:?global$/i>, the pragma will be globally enabled for B<all> code compiled after the current C<no indirect> statement, except for code that is in the lexical scope of C<use indirect>.
 105 This option may come indifferently before or after the C<fatal> or C<hook> options, in the case they are also passed to L</unimport>.
 106
 107 The global policy applied is the one resulting of the C<fatal> or C<hook> options, thus defaults to a warning when none of those are specified :
 108
 109     no indirect 'global';                # warn for any indirect call
 110     no indirect qw<global fatal>;        # die on any indirect call
 111     no indirect 'global', hook => \&hook # custom global action
 112
 113 Note that if another policy is installed by a C<no indirect> statement further in the code, it will overrule the global policy :
 114
 115     no indirect 'global';  # warn globally
 116     {
 117      no indirect 'fatal';  # throw exceptions for this lexical scope
 118      ...
 119      require Some::Module; # the global policy will apply for the
 120                            # compilation phase of this module
 121     }
 122
 123 =back
 124
 125 =cut
 126
 127 sub unimport {
 128  shift;
 129
 130  my $hook;
 131  my $global;
 132  while (@_) {
 133   my $arg = shift;
 134   if ($arg eq 'hook') {
 135    last if $hook;
 136    $hook = shift;
 137   } elsif ($arg =~ /^:?fatal$/i) {
 138    last if $hook;
 139    $hook = sub { die msg(@_) };
 140   } elsif ($arg =~ /^:?global$/i) {
 141    $global = 1;
 142   }
 143  }
 144  $hook = sub { warn msg(@_) } unless defined $hook;
 145
 146  $^H |= 0x00020000;
 147  if ($global) {
 148   delete $^H{+(__PACKAGE__)};
 149   _global($hook);
 150  } else {
 151   $^H{+(__PACKAGE__)} = _tag($hook);
 152  }
 153
 154  return;
 155 }
 156
 157 =head2 C<import>
 158
 159 Magically called at each C<use indirect>. Turns the module off.
 160
 161 As explained in L</unimport>'s description, an C<use indirect> statement will lexically override a global policy previously installed by C<no indirect 'global', ...> (if there's one).
 162
 163 =cut
 164
 165 sub import {
 166  $^H |= 0x00020000;
 167  $^H{+(__PACKAGE__)} = _tag(undef);
 168
 169  return;
 170 }
 171
 172 =head1 FUNCTIONS
 173
 174 =head2 C<msg $object, $method, $file, $line>
 175
 176 Returns the default error message that C<indirect> generates when an indirect method call is reported.
 177
 178 =cut
 179
 180 sub msg {
 181  my $obj = $_[0];
 182
 183  join ' ', "Indirect call of method \"$_[1]\" on",
 184            ($obj =~ /^\s*\{/ ? "a block" : "object \"$obj\""),
 185            "at $_[2] line $_[3].\n";
 186 };
 187
 188 =head1 CONSTANTS
 189
 190 =head2 C<I_THREADSAFE>
 191
 192 True iff the module could have been built with thread-safety features enabled.
 193
 194 =head2 C<I_FORKSAFE>
 195
 196 True iff this module could have been built with fork-safety features enabled.
 197 This will always be true except on Windows where it's false for perl 5.10.0 and below .
 198
 199 =head1 DIAGNOSTICS
 200
 201 =head2 C<Indirect call of method "%s" on object "%s" at %s line %d.>
 202
 203 The default warning/exception message thrown when an indirect method call on an object is found.
 204
 205 =head2 C<Indirect call of method "%s" on a block at %s line %d.>
 206
 207 The default warning/exception message thrown when an indirect method call on a block is found.
 208
 209 =head1 ENVIRONMENT
 210
 211 =head2 C<PERL_INDIRECT_PM_DISABLE>
 212
 213 If this environment variable is set to true when the pragma is used for the first time, the XS code won't be loaded and, although the C<'indirect'> lexical hint will be set to true in the scope of use, the pragma itself won't do anything.
 214 In this case, the pragma will always be considered to be thread-safe, and as such L</I_THREADSAFE> will be true.
 215 This is useful for disabling C<indirect> in production environments.
 216
 217 Note that clearing this variable after C<indirect> was loaded has no effect.
 218 If you want to re-enable the pragma later, you also need to reload it by deleting the C<'indirect.pm'> entry from C<%INC>.
 219
 220 =head1 CAVEATS
 221
 222 The implementation was tweaked to work around several limitations of vanilla C<perl> pragmas : it's thread safe, and does not suffer from a C<perl 5.8.x-5.10.0> bug that causes all pragmas to propagate into C<require>d scopes.
 223
 224 Before C<perl> 5.12, C<meth $obj> (no semicolon) at the end of a file is not seen as an indirect method call, although it is as soon as there is another token before the end (as in C<meth $obj;> or C<meth $obj 1>).
 225 If you use C<perl> 5.12 or greater, those constructs are correctly reported.
 226
 227 With 5.8 perls, the pragma does not propagate into C<eval STRING>.
 228 This is due to a shortcoming in the way perl handles the hints hash, which is addressed in perl 5.10.
 229
 230 The search for indirect method calls happens before constant folding.
 231 Hence C<my $x = new Class if 0> will be caught.
 232
 233 =head1 DEPENDENCIES
 234
 235 L<perl> 5.8.1.
 236
 237 A C compiler.
 238 This module may happen to build with a C++ compiler as well, but don't rely on it, as no guarantee is made in this regard.
 239
 240 L<XSLoader> (standard since perl 5.006).
 241
 242 =head1 AUTHOR
 243
 244 Vincent Pit, C<< <perl at profvince.com> >>, L<http://www.profvince.com>.
 245
 246 You can contact me by mail or on C<irc.perl.org> (vincent).
 247
 248 =head1 BUGS
 249
 250 Please report any bugs or feature requests to C<bug-indirect at rt.cpan.org>, or through the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=indirect>.
 251 I will be notified, and then you'll automatically be notified of progress on your bug as I make changes.
 252
 253 =head1 SUPPORT
 254
 255 You can find documentation for this module with the perldoc command.
 256
 257     perldoc indirect
 258
 259 Tests code coverage report is available at L<http://www.profvince.com/perl/cover/indirect>.
 260
 261 =head1 ACKNOWLEDGEMENTS
 262
 263 Bram, for motivation and advices.
 264
 265 Andrew Main and Florian Ragwitz, for testing on real-life code and reporting issues.
 266
 267 =head1 COPYRIGHT & LICENSE
 268
 269 Copyright 2008,2009,2010,2011 Vincent Pit, all rights reserved.
 270
 271 This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.
 272
 273 =cut
 274
 275 1; # End of indirect